Sharepoint Backup Scripts

Replies to This Discussion

Permalink Reply by Christian Ståhl on June 4, 2009 at 8:04pm

Hi Senthil, i dont work that much with backups, and i have not have this specific needs my self. Could powershell help you out here? Check out this at codplex, Full SharePoint backup with Powershell script.

▶ Reply to This

Permalink Reply by Senthil Kumar on June 5, 2009 at 7:43am

Hey Christian Ståhl,

Thanx for the reply, The link which you provided was helpful..But my requirement is i wann to take back up of all the site collections and multiple web apps. Any way thanx a ton for your help

Thanks,
K.R. Senthil Kumar

▶ Reply to This

Permalink Reply by Senthil Kumar on June 9, 2009 at 2:36pm

Hi All,

At last i have fond a script and it is working great.. Please find below..

Copy and paste the below script to the notepad and name "name.vbs"
create a batch script to run this VB Script
Schedule it.. It works great buddies..
************************************************************************************************
Option Explicit
Const STSADM_PATH = _
"C:\Program Files\Common Files\Microsoft Shared\web server extensions\12\BIN\stsadm"
Dim objFso, objFolder, objFiles, objFile, objShell, objExec, strResult, objXml, objSc,objUrl, strUrl, strFileName, strCmd
Set objFso = CreateObject("Scripting.FileSystemObject")
Set objFolder = objFso.GetFolder("C:\backup\")
Set objFiles = objFolder.Files
WScript.Echo "Begin backup"
' Delete all backup files currently present in the backup folder.
For Each objFile in objFiles
objFile.Delete(True)
Next
' Retrieves all site collections in XML format.
Set objShell = CreateObject("WScript.Shell")
Set objExec = objShell.Exec(STSADM_PATH & " -o enumsites -url http://woodgrove/")
strResult = objExec.StdOut.ReadAll
WScript.Echo strResult
' Load XML in DOM document so it can be processed.
Set objXml = CreateObject("MSXML2.DOMDocument")
objXml.LoadXML(strResult)
' Loop through each site collection and call stsadm.exe to make a backup.
For Each objSc in objXml.DocumentElement.ChildNodes
strUrl = objSc.Attributes.GetNamedItem("Url").Text
strFileName = "C:\backup\" & Replace(Replace(strUrl, "http://", ""), "/", "_") & _
".bak"
strCmd = STSADM_PATH & " -o backup -url """ + strUrl + """ -filename """+ strFileName + """"
WScript.Echo "Backing up site collection " & strUrl & " to file " & strFileName & " using the following command " & strCmd
objShell.Exec(strCmd)
Next
WScript.Echo "Backup of portal site collections successful"
*********************************************************************************************************************

▶ Reply to This

Permalink Reply by Christian Ståhl on June 9, 2009 at 2:41pm

Thats cool Senthil, this one seems to be very usefull when you come to an automatic backup. Nice that you solved this with VB and to enum sites, thats one of the new STSADM commands in SP2 or? Thanks for your sharing!

▶ Reply to This

▶ Reply to This